Unterschied zwischen Modul und Pragma

[Aqua]

Hallo!

HTML::Template ist ein Modul.
strict ist ein Pragma.

Warum?
Was ist ein Pragma?

Danke!
Aqua

[Philipp Hasenfratz]

Halihallo Aqua

HTML::Template ist ein Modul.
strict ist ein Pragma.
Warum?
Was ist ein Pragma?

Ein Pragma ist eine Compilerdirektive. Z.B. sagst du dem Compiler über
use strict, dass er im "strengen Modus" kompilieren soll. Ein Pragma
ist kein ausführbarer Code, sondern eine Anweisung wie der Compiler
sich verhalten soll. Du siehst:
Mit einem Modul ist das absolut nicht zu vergleichen. Es entspricht
vielmehr einem Compilerschalter, den man aber nicht über die
Kommandozeile übergibt, sondern eben direkt in einem Perlscript steuern
kann. Beispiel: use warnings und -w Schalter ist äquivalent.

Ein Modul ist... naja, du weisst es... eine Ansammlung von Code welcher
einem bestimmten Zweck dienlich ist.

Es ist verwirrend, da sowohl Pragmas als auch Module über use
"geschaltet" werden; deine Frage belegt dies.

Also: Ein Pragma beeinflusst den Compiler, ein Modul wird vom
Compiler ggf. eingelesen/ausgeführt.

Viele Grüsse

Philipp

[Bert Randolf]

Hallo,

neben strict ist auch ein "Modul" :)
cat strict.pm

package strict;

$strict::VERSION = "1.03";

my %bitmask = (
refs => 0x00000002,
subs => 0x00000200,
vars => 0x00000400
);

sub bits {
    my $bits = 0;
    my @wrong;
    foreach my $s (@_) {
        push @wrong, $s unless exists $bitmask{$s};
        $bits |= $bitmask{$s} || 0;
    }
    if (@wrong) {
        require Carp;
        Carp::croak("Unknown 'strict' tag(s) '@wrong'");
    }
    $bits;
}

my $default_bits = bits(qw(refs subs vars));

sub import {
    shift;
    $^H |= @_ ? bits(@_) : $default_bits;
}

sub unimport {
    shift;
    $^H &= ~ (@_ ? bits(@_) : $default_bits);
}

1;
__END__

=head1 NAME

strict - Perl pragma to restrict unsafe constructs

=head1 SYNOPSIS

use strict;

use strict "vars";
    use strict "refs";
    use strict "subs";

use strict;
    no strict "vars";

=head1 DESCRIPTION

If no import list is supplied, all possible restrictions are assumed.
(This is the safest mode to operate in, but is sometimes too strict for
casual programming.)  Currently, there are three possible things to be
strict about:  "subs", "vars", and "refs".

=over 6

=item C<strict refs>

This generates a runtime error if you
use symbolic references (see L<perlref>).

use strict 'refs';
    $ref = $foo;
    print $$ref;        # ok
    $ref = "foo";
    print $$ref;        # runtime error; normally ok
    $file = "STDOUT";
    print $file "Hi!";  # error; note: no comma after $file

There is one exception to this rule:

$bar = &{'foo'};
    &$bar;

is allowed so that C<goto &$AUTOLOAD> would not break under stricture.

=item C<strict vars>

This generates a compile-time error if you access a variable that wasn't
declared via C<our> or C<use vars>,
localized via C<my()>, or wasn't fully qualified.  Because this is to avoid
variable suicide problems and subtle dynamic scoping issues, a merely
local() variable isn't good enough.  See L<perlfunc/my> and
L<perlfunc/local>.

use strict 'vars';
    $X::foo = 1;         # ok, fully qualified
    my $foo = 10;        # ok, my() var
    local $foo = 9;      # blows up

package Cinna;
    our $bar;                   # Declares $bar in current package
    $bar = 'HgS';               # ok, global declared via pragma

The local() generated a compile-time error because you just touched a global
name without fully qualifying it.

Because of their special use by sort(), the variables $a and $b are
exempted from this check.

=item C<strict subs>

This disables the poetry optimization, generating a compile-time error if
you try to use a bareword identifier that's not a subroutine, unless it
is a simple identifier (no colons) and that it appears in curly braces or
on the left hand side of the C<< => >> symbol.

use strict 'subs';
    $SIG{PIPE} = Plumber;       # blows up
    $SIG{PIPE} = "Plumber";     # just fine: bareword in curlies always ok
    $SIG{PIPE} = &Plumber;     # preferred form

=back

See L<perlmodlib/Pragmatic Modules>.

=head1 HISTORY

C<strict 'subs'>, with Perl 5.6.1, erroneously permitted to use an unquoted
compound identifier (e.g. CFoo::Bar) as a hash key (before C<< => >> or
inside curlies), but without forcing it always to a literal string.

Starting with Perl 5.8.1 strict is strict about its restrictions:
if unknown restrictions are used, the strict pragma will abort with

Unknown 'strict' tag(s) '...'

=cut

Bert

[Philipp Hasenfratz]

Halihallo Bert

neben strict ist auch ein "Modul" :)

Ich habe befürchtet, dass dieser Hinweis folgen wird ;-)
Ja, das strict Pragma (wie alle anderen auch) haben einen modularen
"Background". Man darf sagen, dass dies zur Vereinfachung des Lebens
des Programmierers so ist, denn, das eigentliche strict-Pragma (im
Script über $^H steuerbar) ist etwas "unhandlich", es ist doch
wesentlich "einfacher" einfach "use strict" oder "no use strict" zu
schreiben.

Viele Grüsse

Philipp