Element in Kopfzeile

[ThomasM]

Hallo whine,

Die Ausgabe sollte in etwa so aussehen
…

Probiere es so:

<?xml version="1.0" encoding="UTF-8"?>  
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"  
  xmlns:fo="http://www.w3.org/1999/XSL/Format">  
  
  <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>  
  
  <xsl:template match="PUBLICATION/SECTION_LIST">  
    <fo:root font-family="Arial, Helvetica, sans-serif">  
  
      <fo:layout-master-set>  
        <fo:simple-page-master master-name="Standardseite"  
          page-height="297mm" page-width="210mm" margin-top="8mm" margin-left="20mm" margin-bottom="24mm" margin-right="7mm">  
          <fo:region-body margin-top="22mm" margin-left="0mm" margin-bottom="20mm" margin-right="0mm"/>  
          <fo:region-before extent="20mm"/>  
          <fo:region-after extent="20mm"/>  
        </fo:simple-page-master>  
      </fo:layout-master-set>  
  
      <fo:page-sequence master-reference="Standardseite">  
        <fo:static-content flow-name="xsl-region-before">  
          <fo:block color="#00F" background-color="#FFC">  
            <fo:retrieve-marker retrieve-class-name="kopfzeile" retrieve-boundary="page-sequence"/>  
          </fo:block>  
        </fo:static-content>  
        <fo:static-content flow-name="xsl-region-after">  
          <fo:block>Inhalt …</fo:block>  
        </fo:static-content>  
        <fo:flow flow-name="xsl-region-body">  
          <xsl:apply-templates select="SECTION"/>  
        </fo:flow>  
      </fo:page-sequence>  
  
    </fo:root>  
  </xsl:template>  
  
  <xsl:template match="SECTION">  
    <fo:block break-before="page">  
      <fo:marker marker-class-name="kopfzeile">  
        <xsl:value-of select="concat('S. ', position(), ' ',NAME)"/>  
      </fo:marker>  
      <xsl:apply-templates select="PRODUCT_LIST/PRODUCT"/>  
    </fo:block>  
  
  </xsl:template>  
  
  <xsl:template match="PRODUCT">  
    <fo:block><xsl:value-of select="concat('Nummer ', NUMBER)"/></fo:block>  
  </xsl:template>  
  
</xsl:stylesheet>

Grüße,
Thomas