Iris: Excel Volleyballturnier - Tabelle

Liebe "Helferlein"

Wir haben mit unserer Excelformel ein Problem. Wir möchten 3 Formeln verbinden (also 3 in ein Feld):

Wenn Feld 1>Feld 2; Dann 2; wenn nicht 0
Wenn Feld 1=Feld 2; Dann 1
Wenn Feld 1 bis Feld 2 Ist leer; Dann 0

oder die 3. Formel

Wenn Feld 1 bis Feld 2 ist eine 0; Dann 0

Es funktioniert nicht mit der ISTLEER Formel: =WENN((P9=Q9;"1");WENN(P9>Q9;"2";"0");WENN(ISTLEER(P9);"0"))

(Fehlermeldung: "Mit dieser Formel gibt es ein Problem......."

Und bei der anderen weiß ich nicht was rein muss: WENN((P9=Q9;"1");WENN(P9>Q9;"2";"0");WENN(P9:Q9........;"0"))

Oder funktioniert das nicht?

Danke für Eure Hilfe

Edit Rolf B: Code als Code markiert

  1. Das WENN-ISTLEER braucht noch einen Wert für "sonst".

    F1 bis F2 ... würde ich über UND abbilden. Wenn F1=0 UND F2=0.

    1. =WENN((P9=Q9;"1");WENN(P9>Q9;"2";"0");WENN(P9=0UNDQ9=0;"0"))

      =WENN((P12=Q12;"1");WENN(P12>Q12;"2";"0");WENN((P9=0)UND(Q9=0);"0"))

      SO?

      oder wie? Geht irgendwie alles nicht. 😟

      1. Hallo Iris,

        ich empfehle Dir ein Excel Einsteigerbuch. Du hast ja offenbar noch kaum Kenntnisse in logischen Formeln. Was soll das denn erstmal werden, wenn Du die Summenformeln zum Integrieren der Spielergebnisse schreiben willst?

        =WENN((P12=Q12;"1");WENN...
              ?           ?
        

        Was sollen die Klammern, unter die ich das Fragezeichen geschrieben habe? Zum WENN gehören sie nicht, und als eigenständiger Klammerausdruck ergeben sie keinen Sinn, weil das Semikolon (das Funktionsparameter trennt) drin steht. Ich würde annehmen, dass sie beide wegmüssen.

        WENN ist eine Funktion mit 3 Parametern. WENN(BEDINGUNG;DANN;SONST). Alle 3 Teile müssen für sich Sinn ergeben, und wenn man mit dem kompletten WENN nicht zurecht kommt, dann kann man entweder den Formelhelfer von Excel verwenden (dieser fx Button neben dem Formeleingabefeld) oder man schreibt die 3 Teile erstmal separat in Zellen und bringt sie zum Funktionieren, und kopiert sie nachher in das WENN(BEDINGUNG;DANN;SONST) Muster hinein.

        Was mir gerade noch auffällt: Du setzt die ermittelten Siegpunkte in Anführungszeichen? Du möchtest die doch nachher aufaddieren, oder? Dann müssen das auch Zahlen sein. Lass diese Anführungszeichen weg.

        Rolf

        --
        sumpsi - posui - obstruxi
      2. Hallo,

        SO?

        UND ist wie WENN bei Excel und Konsorten eine Funktion: Also UND( a ; b).

        Gruß
        Kalk

  2. Hallo Iris,

    "Mit dieser Formel gibt es ein Problem......."

    Ja, sicher. Sortiere mal deine Klammern. Und von der Logik her sollte die Abfrage, ob überhaupt Werte da sind, als erstes erfolgen.

    Wenn Feld 1 bis Feld 2 ist eine 0; Dann 0

    Okay, beim Volleyball ist diese Prüfung sinnvoll, weil bis 15 gespielt.... ups? Meine Volleyballzeiten sind lange vorbei, man zählt heute ganz anders und bis 25?! Egal, ein 0:0 kommt nicht vor. Insofern kannst Du entweder eine Abfrage auf "beides Leer" oder "beides 0" machen, es kommt inhaltlich auf's Gleiche heraus. Als Programmierer würde ich aber immer ISTLEER (oder ANZAHL) verwenden, weil Leer und 0 nicht das gleiche sind.

    ISTLEER ist für Einzelzellen gedacht. ISTLEER(A1:A10) liefert FALSE, sobald die erste Zelle im Bereich gefüllt ist. Wenn Du prüfen willst, ob ein Bereich mit Zahlen gefüllt ist, verwende die ANZAHL Funktion. Die zählt, wieviele Zellen eine Zahl enthalten (nicht verwechseln mit ANZAHL2, die zählt die Zellen, die irgendwas enthalten, nicht nur Zahlen).

    Also:

    =WENN(ANZAHL(P9:Q9)=2;WENN(P9>Q9;2;WENN(P9=Q9;1;0));0)

    Ich selbst drehe sowas gerne herum, diese ";0" ganz am Schluss ist der SONST-Fall der Anzahl2-Prüfung, und die ganzen WENNs dazwischen machen das schwer erkennbar.

    =WENN(ANZAHL(P9:Q9)<2;0;WENN(P9>Q9;2;WENN(P9=Q9;1;0)))

    Wenn es so herum steht, ist die Anzahl-Abfrage vorne erledigt und alles andere kann für sich stehen. Bis auf Klammern, die zu zählen bleibt einem nicht erspart.

    Ich habe jetzt eine Weile überlegt, ob man die Logik so ändern muss, dass nicht an 2 Stellen die 0 stehen muss, aber das macht es nicht einfacher oder lesbarer.

    Eine Spielauswertung eines ganzen Turniers ist auf diese Weise aber sehr mühsam. Da muss man eine Menge dieser Formeln durch die Welt kopieren - viel Glück 😉

    Rolf

    --
    sumpsi - posui - obstruxi
    1. Hab`s

      =(P9>0)*(Q9>0)*(P9=Q9)+2*(P9>Q9)

      1. Hallo IrisL,

        ja, so geht's auch, das ist die Hacker-Variante. Wenn Dein drei Monate älteres Ich das noch kapiert, ist es ok.

        Diese Technik setzt darauf, dass Excel bestimmte Werten Zahlenersatz zuordnet: WAHR=1, FALSCH=0 und LEER=0. Ich wollte Dir diesen Weg bewusst nicht vorschlagen, denn "lesbar" ist das nicht.

        Rolf

        --
        sumpsi - posui - obstruxi
        1. Hallo,

          ja, so geht's auch, das ist die Hacker-Variante. Wenn Dein drei Monate älteres Ich das noch kapiert, ist es ok.

          Diese Technik setzt darauf, dass Excel bestimmte Werten Zahlenersatz zuordnet: WAHR=1, FALSCH=0 und LEER=0. Ich wollte Dir diesen Weg bewusst nicht vorschlagen, denn "lesbar" ist das nicht.

          doch, das finde ich durchaus sehr gut lesbar. Der einzige Nachteil (den du am Rande erwähnst) ist der, dass man sich auf bestimmte Werte verlässt. Damit ist die Lösung eben nicht ohne Einschränkungen portierbar.

          Alle mir bekannten Systeme bilden ein boolsches false auf numerisch 0 ab, die meisten ein boolsches true auf 1. Es gibt aber auch Spezialisten, die true auf -1 abbilden. Ich erinnere mich ans alte Commodore64-BASIC ...

          Immer eine Handbreit Wasser unterm Kiel
           Martin

          --
          Wenn ich den See seh, brauch ich kein Meer mehr.
      2. Hallo IrisL,

        =(P9>0)*(Q9>0)*(P9=Q9)+2*(P9>Q9)

        Übrigens - Wenn P9=Q9 ist, dann ist der Test (P9>0)*(Q9>0) redundant. Die beiden sind gleich, also reicht es, einen von beiden zu testen.

        Es genügt also

        =(P9>0)*(P9=Q9)+2*(P9>Q9)

        Rolf

        --
        sumpsi - posui - obstruxi
    2. Hi,

      Okay, beim Volleyball ist diese Prüfung sinnvoll, weil bis 15 gespielt.... ups? Meine Volleyballzeiten sind lange vorbei, man zählt heute ganz anders und bis 25?!

      Ja, dafür können beide Teams punkten, nicht nur das, das den Aufschlag hat.

      cu,
      Andreas a/k/a MudGuard