Dropdownmenü über Datenbank füllen

[Angehende Informatik-Kaufleute bfw OL]

Hallo kann uns jemand dabei helfen ein Dropdownmenü über eine Datenbank zu füllen. Wir ertellen in Form einer Projektarbeit eine Homepage. Nach unseren Vorstellungen sollte die Dropdowns durch eine Access- Datenbank gefüllt werden. Leider kriegen wir hier keinen Fuss auf den Boden. Wir arbeiten unter w95 mit Frontpage98.
Den einfachen Datenbankzugriff über den Assistenten und ASP klappt aber das andere nicht.
Wir würden uns über jede Anregung freuen. Anmekren möchten wir noch, dass unsere Java und HTML Kenntnisse sehr beschränkt sind. Wie gesagt "angehende"
Besten Dank im voraus.

Marco Schilling

[Ludwig Ruderstaller]

Hallo kann uns jemand dabei helfen ein Dropdownmenü über eine Datenbank zu füllen. Wir ertellen in Form einer Projektarbeit eine Homepage. Nach unseren Vorstellungen sollte die Dropdowns durch eine Access- Datenbank gefüllt werden.

etwa so:

<select name="berufe"><option value="">alle</option><% Set da = db.EXECUTE("SELECT * FROM berufsgruppe")%>
   <% While NOT da.EOF %><option value="<% =da("berufsgruppeID") %>"><% =da("berufsgruppe") %></option><% da.MoveNext : Wend %></select>

lg Ludwig

[Stefan Falz]

Hallo kann uns jemand dabei helfen ein Dropdownmenü über eine Datenbank zu füllen. Wir ertellen in Form einer Projektarbeit eine Homepage. Nach unseren Vorstellungen sollte die Dropdowns durch eine Access- Datenbank gefüllt werden. Leider kriegen wir hier keinen Fuss auf den Boden. Wir arbeiten unter w95 mit Frontpage98.

Hallo,

eigentlich ganz einfach:

<%
' --- Auswahl der Datenbankfelder
SQL = "SELECT OptKZ, OptName FROM tblOptions"

' --- Erstellen des Recordsets
Set OptRS = Server.CreateObject("ADODB.Recordset")

' --- Öffnen des Recordsets
    OptRS.Open SQL, OptConn

' --- Abfrage, ob mind. 1 Satz gefilter wurde
    If Not OptRS.EOF Then

' --- Beginn der Auswahlliste
        Response.Write "<select name=""Auswahl"" size=""1"">"

' --- Für alle gefilterten Datensätze
        Do While Not OptRS.EOF

' --- Ausgabe des Auswahllistenfelds
            Response.Write "<option value=""" & OptRS.Fields("OptKZ") & """>" & OptRS.Fields("OptName")

' --- Nächster Datensatz
            OptRS.MoveNext
        Loop

' --- Ende der Auswahlliste
        Response.Write "</select>"
    End if

' -- Schließen des Recordsets
    OptRS.Close

' --- Zerstören des Objekts (WICHTIG)
Set OptRS = Nothing
%>

Tschau, Stefan