nicht angemeldet
XHTML-Transformation
Hallo zusammen,
ich möchte aus einem XML-File und einem XSL-File ein valides XHTML-Dokument transformieren. Serverseitig mit PHP. Das klappt auch soweit alles. Nur hat mit der Transformator xmlns-Attribute in den HTML-Code. Wie kann ich diese entfernen? Ich habe sonst kein valides XHTML.
mein XSL-File:
<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" doctype-public="-//W3C//DTD XHTML 1.1//EN" doctype-system="http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd" encoding="iso-8859-1" />
<xsl:template match="/">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<title>Layout und Contenttrennung mit XML, XSLT, serverseitigen Scriptsprachen und CSS</title>
<link rel="stylesheet" href="layout.css" type="text/css" />
</head>
<body>
<xsl:apply-templates />
</body>
</html>
</xsl:template>
<xsl:template match="titel">
<h1><xsl:value-of select="." /></h1>
</xsl:template>
<xsl:template match="text">
<div id="box"><p><xsl:value-of select="." /></p></div>
</xsl:template>
<xsl:template match="liste">
<ul class="liste"><xsl:apply-templates /></ul>
</xsl:template>
<xsl:template match="listenpunkt">
<li><xsl:value-of select="." /></li>
</xsl:template>
</xsl:stylesheet>
mein HTML-Ergebnis:
<?xml version="1.0" encoding="iso-8859-1"?>
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.1//EN" "http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd">
<html xmlns="http://www.w3.org/1999/xhtml"><head><title>Layout und Contenttrennung mit XML, XSLT, serverseitigen Scriptsprachen und CSS</title><link rel="stylesheet" href="layout.css" type="text/css"/></head><body>
<h1 xmlns="">Ltuosa Ne confraga is de misereo Gallina cur Baiulus ver Angustata</h1>
<div xmlns="" id="box"><p>Sto emo declinatio, fio no orca lac Tergus liquidus semper dis sus silens alma ervum intempestivus. sis Gladius. Dimitto pes frequentatio deficio crocotula, tristifico Almus. Emercor bos supervacuus Ingeniose via res ortus supellectilis administratio edo omnis unus hi cui Orno, per olim gens tres qua Abnuo ibi qui conticeo per vos. Aura spes oro iam voluptuosus incomparabilis, pro lama mica Vomer.</p></div>
<ul xmlns="" class="liste">
<li>Us, tui sus spero his dux difficultas ara Profiteor campeador aqua peto.</li>
<li>Natus, expugno cogo Candide verecundor.</li>
<li>Ixus labor Pannosa voco nam arx fundatio quicumque certo Adeo opportune his tot Superne.</li>
<li>Am fluctivagus Penso Te, leo Ligatio sane festino late, reputo Nomine ambitus profor benevolentia Repecto acer Celeriter inritus.</li>
</ul>
</body></html>
Vielen Dank! Gruß Tobias
-
Hallo,
ich möchte aus einem XML-File und einem XSL-File ein valides XHTML-Dokument transformieren. Serverseitig mit PHP. Das klappt auch soweit alles. Nur hat mit der Transformator xmlns-Attribute in den HTML-Code. Wie kann ich diese entfernen?
mein XSL-File:
<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">[...]
<html xmlns="http://www.w3.org/1999/xhtml">
so:
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns="http://www.w3.org/1999/xhtml">
[...]
<html><title>Layout und Contenttrennung mit XML, XSLT, serverseitigen Scriptsprachen und CSS<title>
Warum selctierst du da nicht den <titel> aus deinem XML?
<title><xsl:value-of select="titel" /><title>Grüße
Thomas-
Hallo Thomas,
vielen 1000 Dank.
| <title>Layout und Contenttrennung mit XML, XSLT, serverseitigen Scriptsprachen und CSS<title>
|
| Warum selctierst du da nicht den <titel> aus deinem XML?
| <title><xsl:value-of select="titel" /><title>Weil ich für viele unterschiedliche Beispiele die gleiche XML-Datei habe und ich sie somit unterscheiden kann. das sind nur Beispielanwendungen. Ich schreibe eine Bachelorarbeit über Trennungsverfahren von Layout, Content und Funktionalität.
Gruß Tobias
-